Enable tls 1.2 for outlook express / windows mails / office 2007 - 2010 , work on xp up to win11

MicrosoftEasyFix51044.vbs

Code:

'**********************************************************************************
'Check whether the Registry Key is exists
'**********************************************************************************
On Error Resume Next
Dim OperationRegistry : Set OperationRegistry=CreateObject("WScript.Shell")
Dim objWMIService : Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")

Dim OSBitNumber

'Get SID because the SYSTEM account cannot modify HKCU directly.
'Dim WshNetwork : Set WshNetwork = CreateObject("WScript.Network")
'MsgBox("Current User Name: " & WshNetwork.UserName)

Dim colProcesses,objProcess,UserSID
Set colProcesses = objWMIService.ExecQuery( _
    "Select name from Win32_Process Where Name = 'explorer.exe'")
For Each objProcess in colProcesses
    objProcess.GetOwnerSid UserSID
    If Not IsNull(UserSID) Then
        Exit For
    End if
Next
'MsgBox (objProcess.ProcessId & ":" & objProcess.Name)
'MsgBox (UserSID)

Dim HKCUKeyPath : HKCUKeyPath = UserSID & "\Software\Microsoft\Windows\CurrentVersion\Internet Settings\SecureProtocols"

OperationRegistry.RegWrite "HKEY_USERS\" & HKCUKeyPath, 2688, "REG_DWORD"
OperationRegistry.RegWrite "HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Internet Settings\SecureProtocols", 2688, "REG_DWORD"

OSBitNumber = GetOSBitNumber

If OSBitNumber = 32 Then
    OperationRegistry.RegWrite "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings\WinHttp\DefaultSecureProtocols", 2560, "REG_DWORD"
Else
    OperationRegistry.RegWrite "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Internet Settings\WinHttp\DefaultSecureProtocols", 2560, "REG_DWORD"
    OperationRegistry.RegWrite "HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Internet Settings\WinHttp\DefaultSecureProtocols", 2560, "REG_DWORD"
End If

'**********************************************************************************
'get OS info 32-Bit or 64-Bit
'**********************************************************************************
Function GetOSBitNumber()
    Dim WS : Set WS=CreateObject("WScript.Shell")
    Dim KeyValue : KeyValue="HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment\PROCESSOR_ARCHITECTURE"
    Dim strVersion : strVersion=WS.RegRead(KeyValue)
    Dim osVersionBitNo
    If InStr(strVersion,"86")>0 Then
        osVersionBitNo=32
    Else
        osVersionBitNo=64
    End If
    GetOSBitNumber=osVersionBitNo   
End Function