Office 2013 post SP1 already at 1.2Gb of updates. How to integrate it?

The updates folder exists for...... updates

 

No. You can use the C2R edition though..

 

Clean install windows on a virtual machine, then install office 20xx. Do office's updates, reboot and then run this vbs as admin:

Spoiler

Code:

Dim oMsi,oFso,oWShellDim Patches,SumInfo
Dim patch,record,msp
Dim qView
Dim sTargetFolder,sMessage
Const OFFICEID = "000-0000000FF1CE}"
Const PRODUCTCODE_EMPTY = ""
Const MACHINESID = ""
Const MSIINSTALLCONTEXT_MACHINE = 4
Const MSIPATCHSTATE_APPLIED = 1
Const MSIOPENDATABASEMODE_PATCHFILE = 32
Const PID_SUBJECT = 3 'Displayname
Const PID_TEMPLATES = 7 'PatchTargets
Set oMsi = CreateObject("WindowsInstaller.Installer")
Set oFso = CreateObject("Scripting.FileSystemObject")
Set oWShell = CreateObject("Wscript.Shell")


'Create the target folder
sTargetFolder = oWShell.ExpandEnvironmentStrings("%TEMP%")&"\Updates"
If Not oFso.FolderExists(sTargetFolder) Then oFso.CreateFolder sTargetFolder
sMessage = "Patches are being copied to the %Temp%\Updates folder." & vbCrLf & "A Windows Explorer window will open after the script has run."
oWShell.Popup sMessage,20,"Office Patch Collector"


'Get all applied patches
Set Patches = oMsi.PatchesEx(PRODUCTCODE_EMPTY,MACHINESID,MSIINSTALLCONTEXT_MACHINE,MSIPATCHSTATE_APPLIED)
On Error Resume Next


'Enum the patches
For Each patch in Patches
    If Not Err = 0 Then Err.Clear
        'Connect to the patch file
        Set msp = oMsi.OpenDatabase(patch.PatchProperty("LocalPackage"),MSIOPENDATABASEMODE_PATCHFILE)
        Set SumInfo = msp.SummaryInformation
        If Err = 0 Then
            If InStr(SumInfo.Property(PID_TEMPLATES),OFFICEID)>0 Then
                'Get the original patch name
                Set qView = msp.OpenView("SELECT `Property`,`Value` FROM MsiPatchMetadata WHERE `Property`='StdPackageName'")
                qView.Execute : Set record = qView.Fetch()
                'Copy and rename the patch to the original file name
                oFso.CopyFile patch.PatchProperty("LocalPackage"),sTargetFolder&"\"&record.StringData(2),TRUE
            End If
        End If 'Err = 0
Next


'patch
oWShell.Run "explorer /e,"&chr(34)&sTargetFolder&chr(34)

It'll extract installed updates files, and they'll ready to be copied in Office 20xx Install folder/updates. To test the result just clean install again windows on the virtual machine and reinstall the updated office with the traditional installer

 

one question, is this script valid to get the updates from visio and project? or just for office ?

 

it works with every office/visio/project update