Office 2016 Pro Plus VL integrate updates

Discussion in 'Microsoft Office' started by Nazzo, Oct 7, 2015.

  1. Nazzo

    Nazzo MDL Novice

    Aug 20, 2012
    4
    18
    0
    #1 Nazzo, Oct 7, 2015
    Last edited: Oct 7, 2015
    Download the updates from Microsoft for your Office edition (32 bit or 64 bit). Example: download the KB2910993 and KB2910994.

    Those updates are in exe format and we need convert to msp. I use Win toolkit; open and click on the menu Tools--Converters--MSP Extractor--Add office updates--Start.

    Extract the iso of Office 2016 Pro Plus VL to a folder. Put the updates converted in the updates folder. When you install, the updates will be integrated.

    If you want silent and custom install, view my post for that.
     
  2. rydeordie99

    rydeordie99 MDL Novice

    Dec 30, 2007
    18
    3
    0
    #2 rydeordie99, Oct 7, 2015
    Last edited by a moderator: Apr 20, 2017
    I use this script which I used with Office 2013. It sees the updates that you have applied on the current system and coverts them into MSP files to place in the updates folder of the install cd.

    save as .vbs

    Code:
    Dim oMsi,oFso,oWShell
    Dim Patches,SumInfo
    Dim patch,record,msp
    Dim qView
    Dim sTargetFolder,sMessage
    Const OFFICEID = "000-0000000FF1CE}"
    Const PRODUCTCODE_EMPTY = ""
    Const MACHINESID = ""
    Const MSIINSTALLCONTEXT_MACHINE = 4
    Const MSIPATCHSTATE_APPLIED = 1
    Const MSIOPENDATABASEMODE_PATCHFILE = 32
    Const PID_SUBJECT = 3 'Displayname
    Const PID_TEMPLATES = 7 'PatchTargets
    Set oMsi = CreateObject("WindowsInstaller.Installer")
    Set oFso = CreateObject("Scripting.FileSystemObject")
    Set oWShell = CreateObject("Wscript.Shell")
    
    'Create the target folder
    sTargetFolder = oWShell.ExpandEnvironmentStrings("%TEMP%")&"\Updates"
    If Not oFso.FolderExists(sTargetFolder) Then oFso.CreateFolder sTargetFolder
    sMessage = "Patches are being copied to the %Temp%\Updates folder." & vbCrLf & "A Windows Explorer window will open after the script has run."
    oWShell.Popup sMessage,20,"Office Patch Collector"
    
    'Get all applied patches
    Set Patches = oMsi.PatchesEx(PRODUCTCODE_EMPTY,MACHINESID,MSIINSTALLCONTEXT_MACHINE,MSIPATCHSTATE_APPLIED)
    On Error Resume Next
    
    'Enum the patches
    For Each patch in Patches
    If Not Err = 0 Then Err.Clear
    'Connect to the patch file
    Set msp = oMsi.OpenDatabase(patch.PatchProperty("LocalPackage"),MSIOPENDATABASEMODE_PATCHFILE)
    Set SumInfo = msp.SummaryInformation
    If Err = 0 Then
    If InStr(SumInfo.Property(PID_TEMPLATES),OFFICEID)>0 Then
    'Get the original patch name
    Set qView = msp.OpenView("SELECT `Property`,`Value` FROM MsiPatchMetadata WHERE `Property`='StdPackageName'")
    qView.Execute : Set record = qView.Fetch()
    'Copy and rename the patch to the original file name
    oFso.CopyFile patch.PatchProperty("LocalPackage"),sTargetFolder&"\"&record.StringData(2),TRUE
    End If
    End If 'Err = 0
    Next
    
    'patch
    oWShell.Run "explorer /e,"&chr(34)&sTargetFolder&chr(34)
     
  3. dante96

    dante96 MDL Junior Member

    Nov 1, 2013
    60
    9
    0
    I use this command
    Example: conv2016-kb2910993-fullfile-x64-glb.exe /extract:C:\MSP